;       簡易デジタル時計 for Hot Soup Processor 3.x
;       Altキーなどを押すとHSPシステムの動作が止まってしまうため
;       表示も停止してしまいます(仕様)

        width 300, 36
        title "簡易デジタル時計"

;       曜日文字列を配列に設定
        Weeks = "Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat"

        mes "今日の日付と現在時刻:"

        repeat

;               日付データを書式化
                Year    = ""+gettime(0)+""              ; 西暦年(4桁:yyyy)
                Month   = strf("%02d", gettime(1))      ; 月    (2桁:MM)
                Week    = Weeks(gettime(2))             ; 曜日  (文字列)
                Day     = strf("%02d", gettime(3))      ; 日    (2桁:dd)
                Hour    = strf("%02d", gettime(4))      ; 時間  (2桁:hh)
                Minute  = strf("%02d", gettime(5))      ; 分    (2桁:mm)
                Second  = strf("%02d", gettime(6))      ; 秒    (2桁:ss)
                MSecond = strf("%03d", gettime(7))      ; ミリ秒(3桁:xxx)

;               変数 Time にまとめる
                Time  = Year + "/" + Month + "/" + Day + "(" + Week + ") "
                Time += Hour + ":" + Minute + ":" + Second + ":" + MSecond

                redraw 0                    ; ちらつきをなくすため仮想描画

                color 255, 255, 255         ; 塗りつぶし色を白
                boxf 0, 17, 224, 36         ; 時刻表示部分を塗りつぶし

                pos 0, 18                   ; カレントポジションを(0, 18)座標に指定
                color 0, 0, 0               ; 文字色を黒
                mes Time                    ; 現在時刻を表示

                redraw 1                    ; 実際に描画反映

                wait 1                      ; ウェイト

        loop